Godot3 で作るマッチ 3 パズルゲーム

###Piece.gd###
extends Node2D

# ピースの色を文字列データとして設定するためのプロパティ
export (String) var color
# マッチした（3つ以上同じ色が並んだ）状態を示すプロパティ
var matched = false
# Sprite ノードの参照
onready var sprite = $Sprite

# ピースを移動させるメソッド
# 引数 target に渡した位置に Piece インスタンスを移動する
func move(target):
	position = target

# マッチした（3つ以上同じ色が並んだ）ときに呼ばれるメソッド
# matched プロパティを true にし、色を半透明にする
func make_matched():
	matched = true
	sprite.modulate = Color(1,1,1,.5)

###Grid.gd###

extends Node2D

# 各色のピースのシーンファイルを要素とした配列
const pieces_scn = [
	preload("res://Pieces/PieceBeige.tscn"),
	preload("res://Pieces/PieceBlue.tscn"),
	preload("res://Pieces/PieceGreen.tscn"),
	preload("res://Pieces/PiecePink.tscn"),
	preload("res://Pieces/PieceYellow.tscn")
]

# x軸方向のグリッド数
var width: = 7
# y軸方向のグリッド数
var height: = 10
# x軸方向のグリッド開始位置（pixel）
var x_start: = 70
# y軸方向のグリッド開始位置（pixel）
var y_start: = 910
# 1グリッドのサイズ（PieceのSpriteのTextureと同じにする）
var grid_size: = 70

# 盤面のピースの配置を表す配列（二次元配列）
var all_pieces = []

# 画面に指を触れた位置
var touched_pos = Vector2()
# 画面から指を離れた位置
var released_pos = Vector2()

# 画面に指が触れているステート、触れている: true / 離れている: false
var is_touching = false
# マッチしたピースの自動処理ステート、処理中: true / 停止中: false
var is_waiting = false

# PiecesContainer ノードの参照
onready var pieces_container = $PiecesContainer

###Grid.gd###

# シーンが読み込まれたら呼ばれる関数
func _ready():
    # ランダムな数を生成する関数の出力結果を毎回ランダムにするための組み込み関数を呼ぶ
	randomize()
    # all_pieces を盤面のグリッドを構成する二次元配列にする
	all_pieces = make_2d_array() # このあと定義
    # ピースを生成して盤面に配置して盤面情報を all_pieces に反映するメソッドを呼ぶ
	spawn_pieces() # このあと定義

# 盤面のグリッドを構成する二次元配列を生成するメソッド
func make_2d_array():
	# array という名前の配列を用意
    var array = []
    # array に x 軸方向のグリッド数だけ空の配列を入れる
	for i in width:
		array.append([])
        # さらにそれぞれの配列に y 軸方向のグリッド数だけ暫定的に null を入れる
		for j in height:
			array[i].append(null)
    # できあがった二次元配列を返す
	return array

# ピースを生成して盤面に配置して盤面情報を board に反映するメソッド
func spawn_pieces():
    # x軸方向のグリッド数だけループ
	for i in width:
        # y軸方向のグリッド数だけループ
		for j in height:
			# 全ピースの二次元配列上で該当グリッドにピースが存在しない場合
            #（ゲーム開始時は全部 null）
            if all_pieces[i][j] == null:
                # 各色のピースのシーンからランダムで１つ選択してインスタンス化
				var index = floor(rand_range(0, pieces_scn.size()))
				var piece = pieces_scn[index].instance()
                # マッチしてしまった場合は、ピースのインスタンスを削除してやり直し
				while match_at(i, j, piece.color): # このあと定義
					piece.queue_free()
					index = floor(rand_range(0, pieces_scn.size()))
					piece = pieces_scn[index].instance()
                # ピースのインスタンスをPiecesContainerノードの子にする
				pieces_container.add_child(piece)
                # グリッドからピクセルに変換した位置にピースのインスタンスを配置
				piece.position = grid_to_pixel(i, j) # このあと定義
                # 全ピースの二次元配列を更新
				all_pieces[i][j] = piece

###Grid.gd###

# 指定したグリッド位置で同じ色ピースが３つ以上並んでいるか確認するメソッド
# 引数columnはx軸のグリッド位置、rowはy軸のグリッド位置、colorはピースの色
func match_at(column, row, color):
    # 指定したグリッドの x 軸方向の位置が3以上の場合
	if column >= 2:
        # 指定したグリッド位置の左隣ともう一つ左隣にピースがある場合
		if all_pieces[column-1][row] != null \
		and all_pieces[column-2][row] != null:
            # 左隣ともう一つ左隣のピースの色が指定したピースの色と同じ場合
			if all_pieces[column-1][row].color == color \
			and all_pieces[column-2][row].color == color:
                # true を返す
				return true
    # 指定したグリッドの y 軸方向の位置が3以上の場合
	if row >= 2:
        # 指定したグリッド位置の下ともう一つ下にピースがある場合
		if all_pieces[column][row-1] != null \
		and all_pieces[column][row-2] != null:
            # 下ともう一つ下のピースの色が指定したピースの色と同じ場合
			if all_pieces[column][row-1].color == color \
			and all_pieces[column][row-2].color == color:
                # true を返す
				return true

# グリッドの位置をピクセルの位置に変換するメソッド
func grid_to_pixel(column, row):
    # 先にピクセル位置出力用に Vector2 型の変数 pixel_pos を定義
	var pixel_pos = Vector2()
    # ピクセル x 座標 = x 軸方向のグリッド開始位置 + グリッドサイズ x グリッド x 座標
	pixel_pos.x = x_start + grid_size * column
    # ピクセル y 座標 = y 軸方向のグリッド開始位置 - グリッドサイズ x グリッド y 座標
	pixel_pos.y = y_start - grid_size * row
    # ピクセル座標を返す
	return pixel_pos

###Grid.gd###

# ピクセルの位置をグリッドの位置に変換するメソッド
func pixel_to_grid(pixel_x, pixel_y) -> Vector2:
	var grid_pos = Vector2()
	grid_pos.x = floor((pixel_x - x_start) / grid_size)
	grid_pos.y = floor((pixel_y - y_start) / -grid_size)
	return grid_pos

###Grid.gd###

# 指定した位置が盤面グリッドの範囲内かどうかを返すメソッド
func is_in_grid(grid_position: Vector2):
	if grid_position.x >= 0 and grid_position.x < width \
	and grid_position.y >= 0 and grid_position.y < height:
        # 盤面グリッドの範囲内だったら true を返す
		return true
	else:
        # 盤面グリッドの範囲外だったら false を返す
		return false

###Grid.gd###

# ゲームのメインループで毎フレーム呼ばれる関数
func _process(_delta):
    # もしマッチングの処理中でなければ
	if not is_waiting:
        # プレイヤーの入力を処理する
		touch_input() # このあと定義

# プレイヤーの入力を処理するメソッド
func touch_input():
    # もし画面に指が触れたら
	if Input.is_action_just_pressed("touch"):
        # 指の位置をピクセルからグリッドに変換
		var start_pos = get_global_mouse_position()
		var start_grid = pixel_to_grid(start_pos.x, start_pos.y)
        # 指の位置が盤面グリッドの範囲内だったら
		if is_in_grid(start_grid):
            # 画面に指を触れた位置を保存
			touched_pos = start_grid
            # ステートを画面に指が触れている状態にする
			is_touching = true
	# もし画面から指が離れたら
    if Input.is_action_just_released("touch"):
        # 指の位置をピクセルからグリッドに変換
		var end_pos = get_global_mouse_position()
		var end_grid = pixel_to_grid(end_pos.x, end_pos.y)
        # もし指の位置が盤面グリッドの範囲内...
        # かつステートが画面に指が触れている状態だったら
		if is_in_grid(end_grid) and is_touching:
            # 指を離した位置情報として保存
			released_pos = end_grid
            # 指が触れた位置と指を離した位置でピースの移動を処理するメソッドを呼ぶ
			touch_and_release() # このあと定義
        # ステートを画面から指が離れている状態にする
		is_touching = false

###Grid.gd###

# 指が触れた位置と指を離した位置を利用してピースの移動を処理するメソッド
func touch_and_release():
    # 指が触れた位置と指が離れた位置との差を計算
	var difference = released_pos - touched_pos
    # x 軸方向の差の絶対値が y 軸方向の差の絶対値より大きい場合
	if abs(difference.x) > abs(difference.y):
        # x 軸方向の差が 0 より大きい場合
		if difference.x > 0:
            # ヘルパーメソッドを呼び、触れた位置のピースと右に隣接するピースを入れ替える
			swap_pieces(touched_pos, Vector2.RIGHT) # このあと定義
        # x 軸方向の差が 0 より小さい場合
		elif difference.x < 0:
            # ヘルパーメソッドを呼び、触れた位置のピースと左に隣接するピースを入れ替える
			swap_pieces(touched_pos, Vector2.LEFT) # このあと定義
    # x 軸方向の差の絶対値が y 軸方向の差の絶対値より小さい場合
	elif abs(difference.x) < abs(difference.y):
        #  y 軸方向の差が 0 より大きい場合
		if difference.y > 0:
            # ヘルパーメソッドを呼び、触れた位置のピースと下に隣接するピースを入れ替える
			swap_pieces(touched_pos, Vector2.DOWN) # このあと定義
        # y 軸方向の差が 0 より小さい場合
		elif difference.y < 0:
            # ヘルパーメソッドを呼び、触れた位置のピースと上に隣接するピースを入れ替える
			swap_pieces(touched_pos, Vector2.UP) # このあと定義

# ピースを入れ替えるヘルパーメソッド
func swap_pieces(pos, dir):
    # 指を触れた位置のピースを全ピースの二次元配列から取得
	var touched_piece = all_pieces[pos.x][pos.y]
    # 指を離した方向に隣接するピースを全ピースの二次元配列から取得
	var target_piece = all_pieces[pos.x + dir.x][pos.y + dir.y]
    # 全ピースの二次元配列上、どちらのピースも存在している場合
	if touched_piece != null and target_piece != null:
        # 全ピースの二次元配列の中から指を触れた位置のピースを指を離した方に隣接するピースで上書きする
		all_pieces[pos.x][pos.y] = target_piece
        # 全ピースの二次元配列上、指を離した方に隣接するピースを指を触れた位置のピースで上書きする
		all_pieces[pos.x + dir.x][pos.y + dir.y] = touched_piece
        # 盤面上、指を触れた位置のピースインスタンスを指を離した方にに1グリッド移動する
		touched_piece.move(grid_to_pixel(pos.x + dir.x, pos.y + dir.y))
        # 盤面上、指を離した方に隣接するピースインスタンスを指を触れた位置へ移動する
		target_piece.move(grid_to_pixel(pos.x, pos.y))
        # ここからマッチしたピースの処理が始まるので、自動処理ステートを処理中にする
		is_waiting = true

###Grid.gd###

func swap_pieces(pos, dir):
	var touched_piece = all_pieces[pos.x][pos.y]
	var target_piece = all_pieces[pos.x + dir.x][pos.y + dir.y]
	if touched_piece != null and target_piece != null:
		all_pieces[pos.x][pos.y] = target_piece
		all_pieces[pos.x + dir.x][pos.y + dir.y] = touched_piece
		touched_piece.move(grid_to_pixel(pos.x + dir.x, pos.y + dir.y))
		target_piece.move(grid_to_pixel(pos.x, pos.y))

        # 以下を追加
        # ここからマッチしたピースの自動処理が開始するので自動処理ステートを処理中にする
		is_waiting = true

###Grid.gd###

func touch_input():
	if Input.is_action_just_pressed("touch"):
		# 省略
	if Input.is_action_just_released("touch"):
		# 省略

        # ここから追加
        # もし処理中だったら
		if is_waiting:
            # マッチしたピースが1組でもあるかチェック > ある限りループ
			while check_matches(): # このあと定義
                pass
            # マッチしたピースが1組もなく処理が完了したら、自動処理ステートを停止中にする
			is_waiting = false

###Grid.gd###

# マッチしたピースが1組でもあるかチェックして結果を返すメソッド
func check_matches() -> bool:
    # 盤面の x軸方向のグリッドでループ
	for i in width:
        # 盤面の y軸方向のグリッドでループ
		for j in height:
            # その グリッドの座標にピースが存在する場合
			if all_pieces[i][j] != null:
                # そのグリッド座標のピースがマッチしていれば true を返してメソッドも終了
				if match_at(i, j, all_pieces[i][j].color):
					return true
    # 全ピースをチェックしてマッチしているピースが一つもなければ false を返す
	return false

###Grid.gd###

# マッチしているピースを見つけてフラグを立てるメソッド
func find_matches():
    # 盤面の x 軸方向のグリッド数だけループ
	for i in width:
        # 盤面の y 軸方向のグリッド数だけループ
		for j in height:
            # そのグリッドの座標にピースが存在する場合
			if all_pieces[i][j] != null:
                # 現在の色をそのグリッド座標のピースの色と定義する
				var current_color = all_pieces[i][j].color
                # もしその x 軸座標が x 軸方向のグリッド数 - 2 より小さければ
				if i < width - 2:
                    # そのピースの右隣とさらにその右隣にピースが存在する場合
					if all_pieces[i+1][j] != null \
					and all_pieces[i+2][j] != null:
                        # それらのピースの色が現在の色と同じ場合
						if all_pieces[i+1][j].color == current_color \
						and all_pieces[i+2][j].color == current_color:
                            # そのピースにフラグが立ってなければ
							if not all_pieces[i][j].matched:
                                # そのピースの matched プロパティを true にしてフラグを立てる
                                # 同時にそのピースのテクスチャの色を半透明にする
								all_pieces[i][j].make_matched()
                            # そのピースの右隣のピースにフラグが立ってなければ
							if not all_pieces[i+1][j].matched:
                                # そのピースの matched プロパティを true にしてフラグを立てる
                                # 同時にそのピースのテクスチャの色を半透明にする
								all_pieces[i+1][j].make_matched()
                            # そのピースの２つ右隣のピースにフラグが立ってなければ
							if not all_pieces[i+2][j].matched:
                                # そのピースの matched プロパティを true にしてフラグを立てる
                                # 同時にそのピースのテクスチャの色を半透明にする
								all_pieces[i+2][j].make_matched()
				# もしそのピースの y 座標が y 軸方向のグリッド数 - 2 より小さければ
                if j < height - 2:
                    # そのピースの上とさらにその上にピースが存在する場合
					if all_pieces[i][j+1] != null \
					and all_pieces[i][j+2] != null:
                        # それらのピースの色が現在の色と同じ場合
						if all_pieces[i][j+1].color == current_color \
						and all_pieces[i][j+2].color == current_color:
                            # そのピースにフラグが立ってなければ
							if not all_pieces[i][j].matched:
                                # そのピースの matched プロパティを true にしてフラグを立てる
                                # 同時にそのピースのテクスチャの色を半透明にする
								all_pieces[i][j].make_matched()
                            # そのピースの上のピースにフラグが立ってなければ
							if not all_pieces[i][j+1].matched:
                                # そのピースの matched プロパティを true にしてフラグを立てる
                                # 同時にそのピースのテクスチャの色を半透明にする
								all_pieces[i][j+1].make_matched()
                            # そのピースの２つ上のピースにフラグが立ってなければ
							if not all_pieces[i][j+2].matched:
                                # そのピースの matched プロパティを true にしてフラグを立てる
                                # 同時にそのピースのテクスチャの色を半透明にする
								all_pieces[i][j+2].make_matched()

###Grid.gd###

func touch_input():
	if Input.is_action_just_pressed("touch"):
		# 省略
	if Input.is_action_just_released("touch"):
		# 省略

		if is_waiting:
            # マッチしたピースが1組でもあるかチェック > ある限りループ
			while check_matches():
                # マッチしたピースを見つけてフラグを立てる
				find_matches()
                # 処理を視覚的にわかりやすくするため0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
			is_waiting = false

###Grid.gd###

# マッチしているピースを削除するメソッド
func delete_matches():
    # 盤面の x 軸方向のグリッド数だけループ
	for i in width:
        # 盤面の y 軸方向のグリッド数だけループ
		for j in height:
            # そのグリッド座標にピースが存在する場合
			if all_pieces[i][j] != null:
                 # そのグリッド座標のピースにフラグが立っていたら
				if all_pieces[i][j].matched:
                    # そのグリッド座標のピースを削除する
					all_pieces[i][j].queue_free()
                    # 全ピースの二次元配列からそのグリッド座標の要素を空にする
					all_pieces[i][j] = null

###Grid.gd###

func touch_input():
	if Input.is_action_just_pressed("touch"):
		# 省略
	if Input.is_action_just_released("touch"):
		# 省略

		if is_waiting:
            # マッチしたピースが1組でもあるかチェック > ある限りループ
			while check_matches():
                # マッチしたピースを見つけてフラグを立てる
				find_matches()
                # 0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
                # フラグを立てたピースを削除する
				delete_matches()
                # 0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
            # マッチしたピースが1組もなく処理が完了したら、処理中状態を無効にする
			is_waiting = false

###Grid.gd###

# 列ごとにピースが存在しないスペースには上にあるピースを移動して詰めるメソッド
func collapse_columns():
    # 盤面の x　軸方向のグリッド数だけループ
	for i in width:
        # 盤面の y　軸方向のグリッド数だけループ
		for j in height:
            # そのグリッド座標にピースが存在しない（null）場合
			if all_pieces[i][j] == null:
                # そのグリッドの y 座標より１つ上の行から一番上の行までのループ
				for k in range(j + 1, height):
                    # 1つ上のグリッドにピースが存在している場合
					if all_pieces[i][k] != null:
                        # １つ上のグリッドのピースを下の空いているグリッドに移動する
						all_pieces[i][k].move(grid_to_pixel(i, j))
                        # 全ピースの二次元配列の現在のグリッド座標に１つ上のピースを入れる
						all_pieces[i][j] = all_pieces[i][k]
                        # 全ピースの二次元配列の１つ上のグリッド座標を空にする
						all_pieces[i][k] = null
                        # ループを抜ける
						break

###Grid.gd###

func touch_input():
	if Input.is_action_just_pressed("touch"):
		# 省略
	if Input.is_action_just_released("touch"):
		# 省略

		if is_waiting:
            # マッチしたピースが1組でもあるかチェック > ある限りループ
			while check_matches():
                # マッチしたピースを見つけてフラグを立てる
				find_matches()
                # 0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
                # フラグを立てたピースを削除する
				delete_matches()
                # 0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
                # 空のスペースに同じ列の上にあるピースを移動して詰める
				collapse_columns()
                # 0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
            # マッチしたピースが1組もなく処理が完了したら、処理中状態を無効にする
			is_waiting = false

###Grid.gd###

func touch_input():
	if Input.is_action_just_pressed("touch"):
		# 省略
	if Input.is_action_just_released("touch"):
		# 省略

		if is_waiting:
            # マッチしたピースが1組でもあるかチェック > ある限りループ
			while check_matches():
                # マッチしたピースを見つけてフラグを立てる
				find_matches()
                # 0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
                # フラグを立てたピースを削除する
				delete_matches()
                # 0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
                # 空のスペースに同じ列の上にあるピースを移動して詰める
				collapse_columns()
                # 0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
                # 空のスペースに新しいピースを生成して配置する
				spawn_pieces()
                # 0.3秒待機
				yield(get_tree().create_timer(0.3), "timeout")
            # マッチしたピースが1組もなく処理が完了したら、処理中状態を無効にする
			is_waiting = false